#!/bin/csh -f
# CDS additional setup

#  If the environment variable CDS_TOP is defined, then execute
#  $CDS_TOP/cds.login.  For example, this might be defined as
#
#	setenv CDS_TOP /sdb/soho/cds
#
#  As well as CDS_TOP, the following optional environment variables can be
#  defined:
#
#	Environment variable	Default definition
#
#	CDS_SITE_LOGIN		(No default.  Should point to a file which
#				defines the following optional evars, as well
#				as any other site-specific evars.)
#
#	CDS_DATA		$CDS_TOP/data
#	CDS_LRG_DATA		$CDS_TOP/lrg_data
#	SOHO_PUB_DATA		/soho-archive/public/data
#
#  The last is used to make the following definitions:
#
#	setenv ANCIL_DATA	$SOHO_PUB_DATA/ancillary
#	setenv SOHO_EAP		$SOHO_PUB_DATA/summary/asplanned
#	setenv SYNOP_DATA	$SOHO_PUB_DATA/synoptic
#	setenv SUMMARY_DATA	$SOHO_PUB_DATA/summary
#	setenv CDS_SUMMARY_DATA $SUMMARY_DATA/cds
#
# Modified, 28-Jan-97, Zarro (GSFC) -- allowed turning off output messages
# Modified, 15-Jan-99, Zarro (GSFC) -- added path to FITS data in SOHO-ARCHIVE
# Modified, 14-Jun-2001, William Thompson (GSFC).
#	Defined new evar SDB_CDS, and restored capability of using SDB
#	databases instead of the truncated list in SSW
#	Defined ZDBASE directly.
# Modified, 19-Jun-2001, William Thompson (GSFC).
#	Added CDS_ATOMIC
# Modified, 03-Jul-2001, William Thompson (GSFC).
#	Renamed from setup.cds_env
# Modified, 18-Jul-2001, William Thompson (GSFC).
#	Remerged with setup.cds_paths

set echo_mess = 0

if ($?ssw_loud) then
 if ($ssw_loud == 1) set echo_mess = 1
endif

if ($?ssw_quiet) then
 if ($ssw_quiet != 1) set echo_mess = 1
endif


if ( $?CDS_TOP ) then 

  if ($echo_mess == 1) echo "Executing $CDS_TOP/cds.login"


#  Keep track of the current definition of IDL_STARTUP.  This shouldn't be
#  changed in the SSW environment, so we need to know what it started as so
#  that it can be changed back.

	if ( $?IDL_STARTUP ) then
		set save_idl_startup = $IDL_STARTUP
		source $CDS_TOP/cds.login
		setenv IDL_STARTUP $save_idl_startup
		unset save_idl_startup
	else
		source $CDS_TOP/cds.login
		unsetenv IDL_STARTUP
	endif

#  If the CDS_TOP environment variable is not set, then simply define those
#  environment variables which can be pointed into the SSW_CDS tree.

else
	if ($echo_mess == 1) echo "Defining CDS environment variables for $SSW tree."
	setenv ZDBASE_CDS +$SSW/soho/cds/data/database 
	if ($?SSWDB) then
	    if (-e $SSWDB/soho/cds/data/plan/database/calib/nis_wave.dbf) then
	        setenv ZDBASE_CDS +$SSWDB/soho/cds/data/plan/database 
	    endif
	endif
	setenv ZDBASE           $ZDBASE_SOHO\:$ZDBASE_CDS
	setenv CDS_SUMMARY_DATA $SUMMARY_DATA/cds
	setenv CDS_ATOMIC	$SSW/soho/cds/data/atomic
	setenv CDS_INFO		$SSW/soho/cds/data/info
	setenv CDS_VDS_CAL_INT	$SSW/soho/cds/data/vds/cal/int
	setenv CDS_GIS_CAL_INT	$SSW/soho/cds/data/gis/cal/int
	setenv CDS_PLAN_TECH    $SSW/soho/cds/data/plan/tech
endif

# Path to CDS_FITS_DATA in SOHO-ARCHIVE

if !($?CDS_FITS_DATA) then

 if ($?CDS_FITS) then
  if ($CDS_FITS != "") setenv CDS_FITS_DATA +$CDS_FITS
 endif

 if ($?CDS_FITS_1) then
  if ($CDS_FITS_1 != "") then 
   if ($?CDS_FITS_DATA) then 
    setenv CDS_FITS_DATA "$CDS_FITS_DATA"":+""$CDS_FITS_1"
   else
    setenv CDS_FITS_DATA +$CDS_FITS_1
   endif
  endif
 endif
endif

#