;*******************************************************************************
; Grating_B_511.pro   Grating Resolution Detector B at Pixel 511
; Klaus Wilhelm                                                02 December 1994
; Lambda_n: Detector A (px 511) in Angstroem ; gt 780 A (1st order only)
; Theta: Angle of incidence
; Beta: Angle of diffraction
; f_n: Focal length for detector A (px 511)
; fs: Sagittal focus (best angular resolution)
; Separated from radiometry.pro                                26 November 1998

pro grating_B_511,lambda_n,d_lam_B_511,mag_B

ra=3200.78   ; mm  radius of grating
px=0.0265    ; mm (Pixel size Detector B) = 70.3045 mm / 2653
d=2777.45d0  ; Angstroem (Grating constant)
dist=70.3045 ; mm  distance between centres of detectors
fc=399.60    ; mm focal length of collimator

;-------------------------------------------------------------------------------
; Optical considerations
;-------------------------------------------------------------------------------

sin_theta=lambda_n/d
cos_theta=sqrt(1-sin_theta^2)
f_n=ra/(1+cos_theta)
param_corr,lambda_n,-1.68,1.0,delta_x ; a and b correction for best angular
                                      ; resolution
f_n=f_n-delta_x
beta=atan(px*2653,f_n)                ; beta for Pixel 511 of Detector B
fs=ra/(cos(beta)+cos_theta)

;-------------------------------------------------------------------------------
; Geometric considerations
;-------------------------------------------------------------------------------

l_2=1327*px                           ; Pixel 511 of Detector B
alpha_0=atan(dist/2,f_n)
zeta=86.8*3.1416/180+alpha_0          ; 3.2 deg between detectors
f=sqrt(f_n^2+(dist/2)^2)
f_lam=sqrt(l_2^2+f^2-2*l_2*f*cos(zeta))
mag_b=f_lam/fc
;-------------------------------------------------------------------------------

px_proj=px*cos(beta-3.2*3.1416/180)
d_lam_B_511=d*cos(beta)*px_proj/f_lam

return
end