;*******************************************************************************
; Lambda_n.pro Calculates the Wavelength on the Grating Normal for Lambda_B_511
; Klaus Wilhelm                                               05 January 1994
; Rev.                                                        01 September 1998
; Separated from radiometry.pro                               26 November 1998

pro Lambda_n,lambda_B_511,lambda_n

; lambda_B_511 (first order) in Angstroem on centre of Detector B
; lambda_n (first order) in Angstroem on centre of Detector A

px_s_b=0.0265                              ; mm  mean pixel size of Detector B
m=1                                        ; in first order
d=2777.45d0                                ; Angstroem (Grating constant)
ra=3200.78                                 ; mm  radius of grating

lambda_n=lambda_B_511                      ; first approximation

sin_theta=m*lambda_n/d
cos_theta=sqrt(1-sin_theta^2)
f_n=ra/(1+cos_theta)
d_lam=d*px_s_b/m/f_n
for i=0,4 do begin                         ; Iteration to improve approximation
  diff=d_lam*(2653-2)                      ; Pixel offset of centre of B
  sin_theta=m*(lambda_n+diff)/d
  cos_theta=sqrt(1-sin_theta^2)
  f_n=ra/(1+cos_theta)
  param_corr,lambda_n+diff,-1.68,1.0,delta_x
                                           ; a and b correction for best
                                           ; angular resolution
  f_n=f_n-delta_x
  d_lam=d*px_s_b/m/f_n
  endfor
lambda_n=lambda_n+diff
return
end