;*******************************************************************************
; Magnification.pro SUMER Magnification Factor and Spectral Resolution Element
; K. W.                                                     05 Jan 1994
; Rev. 2 (Mean pixel size: 0.0265 mm)                       10 Dec 1994
; Short version                                             19 Nov 1996
; Completed for detector B                                  12 May 1997     ++++
; Correction detector B                                     11 Aug. 1998    ????
; The correction of August 1998 was no improvement          01 Sept. 1998   ....
; Corrected to comply with flight S/W                                       ....
; Mean spectral pixel size: Detector A = 0.0266 mm, Detector B = 0.0265 mm  ....
; Mean spatial pixel size: No Change (0.0265 mm for both detectors)         ....
; The September 1, 1998 modification changes the original value of          ....
; Detector A by 0.38 % (0.0266/0.0265) and of B by 0.18 % at 660 A          ....
; and 0.3 % at 1460 A                                                       ....
; Separated from Radiometry.pro                             26 Nov. 1998
; Second order dispersion corrected for detector B          07 June 1999    %%%%
; Rev. of second order dispersion for detector B            15 June 1999    %%%%

pro magnification,wavelength,order,mag_a,d_lam_a,mag_b,d_lam_b ;            ++++
;------------------------------------------------------------------------------

; Wavelength in Angstroem
; mag_a: Magnification slit plane/detector plane for detector A
; d_lam_a: Wavelength interval per pixel on detector A in Angstroem
; mag_b: Magnification slit plane/detector plane for detector B             ++++
; d_lam_b: Wavelength interval per pixel on detector B in Angstroem         ????
; Order of diffraction

d=2777.45d0                     ; in Angstroem, (Grating constant)
ra=3200.78                      ; in mm, radius of grating
fc=399.60                       ; in mm, focal length of collimator

; Detector A

px_s_a=0.0266                   ; in mm                                     ....
                                ; mean spectral pixel size Detector A       ....
                                ; mean spatial pixel size for A + B: 0.0265 ....
sin_theta=order*wavelength/d
cos_theta=sqrt(1-sin_theta^2)
f_lambda=ra/(1+cos_theta)
mag_a=f_lambda/fc
d_lam_a=d*px_s_a/order/f_lambda

; Detector B
lambda_n,order*wavelength,lambda_n ;                                   .... %%%%
grating_b_511,lambda_n,d_lam_b,mag_b ;                                      ....
d_lam_b=d_lam_b/order;                                                      %%%%
return
end