; con_width.pro
; Computes SUMER Line Width Output from Input Width (Detector A)
; Klaus Wilhelm                                             18 January 1997
; Rev. 1 Actual slit widths                                 05 February 1997

; Input width as Doppler width in mÅ
; Output width as Doppler width or as FWHM in mÅ
; Parameter: Slit number

; Measured slit widths:
; Slit no. 1      = 26.04 micro m  +- 0.8% max.  +- 0.5% probable error
; Slit no. 2      =  6.23 micro m  +- 3.2% max.  +- 1.6% probable error
; Slit no. 4(3,5) =  6.27 micro m  +- 3.2% max.  +- 1.6% probable error
; Slit no. 7(6,8) =  1.76 micro m  +- 11 % max.  +- 5.7% probable error

; 1 arcsec corresponds to 6.316 micro m

;-------------------------------------------------------------------------------
; What to do?
; IDL> con_fwhm, slit ; 4 times with slit choices = (6),7,(8)(~0.3),
; (3),4,(5)(~1*120), 2(~1*300) and 1(~4*300)
; This builds up four look-up tables for the de-convolution.
; These tables do not critically depend on the wavelength.
;-------------------------------------------------------------------------------

;*******************************************************************************
; Definition of procedures
;*******************************************************************************

; Magnification.pro    Calculates the SUMER Magnification
; Klaus Wilhelm                                             05 Jan 1994
; Rev. 2 (Mean pixel size: 26.5 micro m)                    10 Dec 1994
; Here given for detector A and 1200 A                      19 January 1997

pro magnification,mag,res,d_lam

; Mag: Magnification slit plane/detector plane
; Res: Resolving power lambda/delta_lambda
; d_lam: Wavelength interval per pixel

px_s_a=0.0265
wavelength=1200.
m=1 ; in first order
d=2777.45d0; Angstroem (Grating constant)
sin_theta=m*wavelength/d
ra=3200.78; mm  radius of grating
cos_theta=sqrt(1-sin_theta^2)
f_lambda=ra/(1+cos_theta)
rc=399.60; mm focal length of collimator
mag=f_lambda/rc
res=m*f_lambda*wavelength/(d*px_s_a)
d_lam=d*px_s_a/m/f_lambda

return 
end
;*******************************************************************************

pro con_width,slit

; Slit (provide slit number as given above)

magnification,mag,res,d_lam

case 1 of
  (slit eq 1): slit_width=26.04
  (slit eq 2): slit_width=6.23
  (slit ge 3) and (slit le 5): slit_width=6.27
  (slit ge 6): slit_width=1.76
  endcase
half_slit_width=fix(500.*d_lam*slit_width*mag/26.5) ; in mA
kernel=fltarr(500)
kernel(250-half_slit_width)=fltarr(2*half_slit_width)+1
fwhm_out_c=fltarr(361) ; calculated output width
for i=40.,400. do begin ; d_lam_d_in = line width convoluted (includes spectro-
; meter width, but not the slit effect (in mÅ)
  gauss=exp(-((findgen(2000)-999.)/i)^2)
  a=convol(gauss,kernel)
  p0=min(where(a ge max(a)/2.)) 
  p1=max(where(a ge max(a)/2.)) 
  fwhm_out_c(i-40)=p1-p0
  endfor
d_lam_d_in=40+indgen(361)
fwhm_in=d_lam_d_in/0.6006
save,filename='con_fwhm_d_lam'+strtrim(fix(slit),2)+'.rst',$
fwhm_out_c,fwhm_in,d_lam_d_in
return
end