;+
; Project     :	STEREO - SSC
;
; Name        :	SSC_MAKE_WHERE_IS_STEREO
;
; Purpose     :	Make "Where is STEREO?" web page.
;
; Category    :	STEREO, Orbit, Graphics
;
; Explanation :	Creates the "Where is STEREO?" web page in the directory
;  	      	$HTDOCS/where.  Calls SSC_MAKE_WHERE_GIF to make the GIF image
;  		and associated text.
;
; Syntax      :	SSC_MAKE_WHERE_IS_STEREO
;
; Inputs      :	None.
;
; Opt. Inputs :	None.
;
; Outputs     :	A GIF file is created showing the spacecraft positions.
;
; Opt. Outputs:	None.
;
; Keywords    :	None.
;
; Calls       :	GET_UTC, UTC2STR, SSC_MAKE_WHERE_GIF
;
; Common      :	None.
;
; Restrictions:	None.
;
; Side effects:	Loads the STEREO ephemerides if not already loaded.
;
; Prev. Hist. :	None.
;
; History     :	Version 1, 09-Nov-2006, William Thompson, GSFC
;
; Contact     :	WTHOMPSON
;-
;
pro ssc_make_where_is_stereo
;
;  Get the current date and time, and reset to the beginning of the current
;  hour.   Convert to character strings to the nearest minute.
;
get_utc,utc,/external
utc.minute = 0
utc.second = 0
utc.millisecond = 0
date = utc2str(utc,/date,/vms)
time = strmid(utc2str(utc,/time),0,5)
;
;  Call SSC_MAKE_WHERE_GIF to make the GIF image and associated text.
;
stereo_path = '$HTDOCS/where/'
ssc_make_where_gif, utc, stereo_path + 'where_is_stereo.gif', $
	infofile=stereo_path + 'where_is_stereo.txt'
;
;  Create the web page.  Start with the standard header.
;
openw, output, stereo_path + 'where_is_stereo.shtml', /get_lun
openr, header, stereo_path + 'header.txt', /get_lun
line = 'String'
while not eof(header) do begin
    readf, header, line
    printf, output, line
endwhile
free_lun, header
;
;  Print out the date and time, and include the image.
;
printf, output, '<H3>Positions of STEREO A and B for ' + date + $
  ' ' + time + ' UT</H3><P>'
printf, output, '<IMG SRC="/where/where_is_stereo.gif" ' +       $
  'ALT="Plot of spacecraft positions"><P>'
;
;  Include the figure caption.
;
openr, caption, stereo_path + 'caption.txt', /get_lun
line = 'String'
while not eof(caption) do begin
    readf, caption, line
    printf, output, line
endwhile
free_lun, caption
;
;  Include the table and footer.
;
openr, footer, stereo_path + 'footer.txt', /get_lun
line = 'String'
while not eof(footer) do begin
    readf, footer, line
    printf, output, line
endwhile
free_lun, footer, output
;
print, ''
print, '**************************************************'
print, '* The file where_is_stereo.shtml has been updated. *'
print, '**************************************************'
print, ''
;
return
end